IRTC Watch: January-February 2006

Introduction

This Internet Raytracing Competition is a great place for Povray fans to strut their stuff. Artists sometimes submit their scene files in addition to their images, providing a great opportunity January-February Stills topic was "Fire And Ice" and the artists didn't disappoint. Most delightfully, four of the six placing images were submitted with source files, giving a great view into scene construction techniques. This first article in a new series here at Mike's Povray Page, IRTC Watch, will focus on tricks used in Sean Day's "Snowman" and Roman Reiner's "Firelake".

The Source

The SDL (scene description language) for each of the scenes discussed below was published on the IRTC website, and are easily downloadable.

Everyone who submits their SDL with their IRTC entry does a service to the rest of us by providing examples. Please remember to respect the creator's work by not abusing the scenes and textures. Also note that not everyone uses Povray on the IRTC. Some scenes are created in MegaPov, while others use self-written renders and other modeling tools. MegaPov scenes will work in Povray with a little modification, though it may not look quite the same.

Snowman

In this rendering, Sean was able to capture the right glinting in snow with a well done texture using the right combination of brilliance, specular highlights, roughness, and surface normals. The snow texture is shown below (slightly reformatted):

#declare snowTex = texture
{
    pigment { color rgb <1, 1, 1> }
    finish {
        ambient 0
        diffuse 0.9
        brilliance 1.75
        specular 1.5
        roughness 0.0001
        reflection 0.025
    }
    normal {
        average
        normal_map {
            [ 1 granite 0.5 scale 0.002 turbulence 1 omega 0.4 lambda 1.2 ]
            [ 1 wrinkles 0.75 scale 0.15 ]
        }
    }
}

We took it for a quick test drive with Povray 3.6.1 and produced a great (though a bit dirty) snowball.

	Anti-aliasing Method 1
	Anti-aliasing Method 2

You may want to consider using anti-aliasing method 1. Anti-aliasing method 2 seems to take some of the graininess that's hard to capture out of the texture. Also, tweaking with the reflection value in the finish provides a great way to adjust the amount of glint off of the snow.

Firelake

We found this image delightful for the blurred lake effect. It was to our great delight to find out that this effect was created from a description on povray.org's tips and tricks to achieve useful things web page. The effect is produced by averaging several different bump normals on the water's surface to 'muddle' up the reflection. The technique takes a base texture with a surface normal and averages several slight variations of the texture. The variations are made my altering the position or rotation with a small random number. Roman expanded on the basic idea with multiple layers of averaged textures to provide more variety to the surface. One of Roman's textures is shown below (again, slightly reformatted) to illustrate the averaging process:

#declare S = seed(0);

#declare mytex = texture {
pigment { rgb 0 }
normal { bumps 0.11 scale 0.10 }
finish { reflection 1.00 }
}

#declare longripplestex = texture {
average
texture_map {
    #local i=0;
    #while (i<30) //blur_samples
      #local mytex = texture { mytex rotate y*360*rand(S) }
      [1 mytex]
      #local i=i+1;
    #end
}
scale z*5
}

We stripped down Roman's scene and re-rendered the water with increasing amounts of averaging to show the difference it makes. Again, this was rendered in Povray 3.6.1

	No Averaging
	Minimal Averaging (12, 2 textures)
	Lots Of Averaging (30, 5 textures)

This is a great trick to add an extra touch to a watery surface.

Closing Remarks

Even thought we only looked at two scenes, this IRTC round produced a wonderful set of images that had authors willing to share their scene files. We want to mention Tekno Frannansa's "Cold Shapes Hot, Hot Shapes Cold" as another great scene with included source. Visit the January-February viewing page and see it all. The March-April topic is "Music" and we're looking forward to what the artists will render next

Thanks to Sean and Roman, as well as all the other artists, who share their scene files for the rest of us to learn from!

Published: 04/21/06
Last Edited: 04/21/06
Copyright (C) 2006 Mike Kost