#include "textures.inc"

global_settings {
    max_trace_level 10
    adc_bailout 1/255
}

camera {
    angle 60
    location <4,4,4>
    look_at <0,0,0>
}

#declare SKY_R = 0.75;  // povbroom
#declare SKY_G = 0.90;  // povbroom
#declare SKY_B = 1.00;  // povbroom

sky_sphere {
   pigment { color rgb <SKY_R, SKY_G, SKY_B>   }
}

light_source { <0,999,1000> color rgb 1.0 }

#declare P_Cloud = pigment {
    wrinkles
    turbulence <0.5, 0.5, 0.5>
    octaves    7
    omega      0.5
    lambda     3
    color_map {
        [0.00 color rgbt <1.00,1.00,1.00,1.00>]
        [0.50 color rgbt <1.00,1.00,1.00,1.00>]
        [0.60 color rgbt <0.50,0.50,0.50,0.50>]
        [1.00 color rgbt <1.00,1.00,1.00,0.00>]
    }
    scale <1200,1200,1200>
}

union {
    plane {
        <0, -1, 0> 0
        texture {
            pigment { P_Cloud }
            finish { ambient 1.0 }
        }
    }

    plane {
        <0, -1, 0> 0
        translate <0, 5, 0>
        texture {
            pigment { P_Cloud }
            finish { ambient 0.6 }
        }
    }

    plane {
        <0, -1, 0> 0
        translate <0, 10, 0>
        texture {
            pigment { P_Cloud }
            finish { ambient 0.8 }
        }
    }

    plane {
        <0, -1, 0> 0
        translate <0, 15, 0>
        texture {
            pigment { P_Cloud }
            finish { ambient 0.4 }
        }
    }
    translate <0, 1000, 0>
}

#declare copper_micro_norm = normal
{
  spotted .5 scale .3

  slope_map
  {
    [0 <1,0>]
    [0.3 <1,0>]
    [0.9 <0,0>]
    [1 <0,0>]
  }
}


#declare chinks = normal
{
  spotted .5 scale 1

  slope_map
  {
    [0 <1,0>]
    [0.60 <1,0>]
    [0.90 <0,0>]
    [1 <0,0>]
  }
}
#declare copper_norm = normal
{
  spotted 1 scale .125

  normal_map
  {
    [0 copper_micro_norm]
    [.6 copper_micro_norm]
    [.6 chinks]
    [1 chinks]
  }
}

plane {
    <0, 1, 0> 0
    texture {
        checker
        texture {
            pigment { color rgb <0, 1, 0> }
            normal { copper_norm } 
        }
        texture {
            pigment { color rgb <0, 0, 1> }
        }
    }
}

sphere {
    <0, 0, 0>, 1
    texture {
        pigment { rgbt <0.8, 0.6, 0.8, 0> }
        finish {
            diffuse 0.2
            ambient 0.0
            reflection 0.8
            metallic
        }
    }
    scale 1
    translate <0, 0.5, 0>
}